Tank Reverb (JMC)
Saturday, January 15, 2005, 07:35 PM
Excellent sounding reverb, courtesy JMC: 


SynthDef("tank", { arg outbus, feedback=0.9,something=0.1;


        var local, in, amp;


        


        in = In.ar(outbus);


        


        amp = Amplitude.kr(Mix.ar(in));


        in = in * (amp > 0.04); // noise gate


        


        in = in * 0.4;


                


        local = LocalIn.ar(2) * feedback;





        local = OnePole.ar(local, something);


        


        local = Rotate2.ar(local[0], local[1], 0.237);


        local = AllpassN.ar(local, 0.05, {Rand(0.01,0.05)}.dup, 2);


                                


        local = DelayN.ar(local, 0.3, {Rand(0.15,0.33)}.dup);


        local = AllpassN.ar(local, 0.15, {Rand(0.03,0.15)}.dup, 2);


        


        local = LeakDC.ar(local);       


        local = local + in;





        4.do {


                var t;


                t = {Rand(0.005,0.02)}.dup;


                local = AllpassN.ar(local, t, t, 1);


        };


                


        LocalOut.ar(local);


        


        ReplaceOut.ar(outbus, local);


}).load(s);